MS-Accessのレポートをページ毎にPDF化する

 仕事で通知書をPDFで作ってメールで配信しようと言うことになって，Access のレポートで通知書を作ることにしたのですが，ページ毎に別のPDFファイルにするのを手作業でやっているとめんどくて気が狂うので自動化を考えてみました。

外のツールを使わないでもできるように今回は Access 2010 を使いました。たぶん，2007でも動作します。

最初に考えて実行したのは次のコード

Sub makePdfFiles()
    
    Const TBL_NAME = "担当者"
    Const RPT_NAME = "通知書"
    Const PDF_PATH = "D:\hogehoge\"
    
    Dim rs As ADODB.Recordset
    Set rs = New ADODB.Recordset
    
    rs.Open TBL_NAME, CurrentProject.Connection, adOpenStatic, adLockReadOnly
    Do While Not rs.EOF
    
        pdfName = rs!部署名 & rs!担当者
        
        DoCmd.OpenReport RPT_NAME, acViewPreview, , "ID=" & rs!ID
        DoCmd.OutputTo acOutputReport, RPT_NAME, acFormatPDF, PDF_PATH & rs!ID & pdfName & ".pdf"
        DoCmd.Close
        
        rs.MoveNext
    
    Loop
    
End Sub

 15行目でフィルタを設定してレポートをプレビューで開いてから，16行目で DoCmd.OutputTo メソッドで PDF に出力しています。出力後は，レポートを閉じます。このやり方ですと，画面上に出力されるページのプレビューが次々表示されます。動きがわかってよろしい，ということでしたらいいのですが，うるさい（あるいは遅い）と感じる場合には次のコードが

 Sub makePdfFiles2()
    
    Const TBL_NAME = "担当者"
    Const RPT_NAME = "通知書2"
    Const PDF_PATH = "D:\hogehoge"
    
    Dim rs As ADODB.Recordset
    Set rs = New ADODB.Recordset
    
    rs.Open TBL_NAME, CurrentProject.Connection, adOpenStatic, adLockReadOnly
    Do While Not rs.EOF
    
        pdfName = rs!部署名 & rs!担当者
        
        CurrentProject.Connection.Execute "UPDATE Target SET ID = " & rs!ID
        DoCmd.OutputTo acOutputReport, RPT_NAME, acFormatPDF, PDF_PATH & rs!ID & pdfName & ".pdf"
        
        rs.MoveNext
    
    Loop
    
End Sub

このコードの場合は，レポートのレコードセットは，Target テーブルと次のようにINNER JOIN されているという前提です。そして Target テーブルには1件だけレコードを登録しておきます。

15行目で Target テーブルのIDを設定しています。それでレポートは1ページだけになります。その後，レポートを開くことなく OutputTo メソッドだけを実行しています。

このやり方ですと，画面には PDF出力の小さなダイアログが表示されるだけになりますので，ちょっとだけ静かになります。