Ext JS に関しては,新しい記事は Sunvisor Lab. ExtJS 別館 にあります。そちらもよろしくお願いいたします。

USBメモリにAutorun.infフォルダを作成

USBメモリを介して広がるウィルスがはやっております。そういうウィルスはUSBメモリにautorun.infを作成して,感染を広げていきます。その対策としては,同じ名前のフォルダをUSBメモリに作成してしまって,autorun.infファイルを作成できないようにするというのが有効だそうです。その作業をやってもらいたいんだけど説明してわかってもらうのが大変。そこで簡単にやってもらおうというスクリプトを作りました。

Dim FSO
Dim flag
 
Set FSO = CreateObject("Scripting.FileSystemObject")
flag = False
For Each Drv In FSO.Drives
    'Dドライブ以降のリムーバブルディスクが対象
    If Drv.DriveLetter > "C" And Drv.DriveType = 1 Then
        If Drv.IsReady Then
            Flag = True
            MakeAutorunFolder(Drv)
        End If
    End If
Next
If Not Flag Then
    MsgBox "対象となるドライブが見つかりませんでした。" & _
        "USBメモリを接続して再度やり直してください", vbInformation
End If
 
Sub MakeAutorunFolder(ADrive)
    sFileName = ADrive & "\autorun.inf"
    sMsg = ADrive & "ドライブのディスクに対策を施しますか?"
    If MsgBox(sMsg, vbYesNo+vbQuestion, "作成") = vbYes Then
        ' WScript.Echo "実行します"
        If FSO.FolderExists(sFileName) Then
            ' WScript.Echo "処理の必要はない。"
        Else
            If FSO.FileExists(sFileName) Then
                ' WScript.Echo "autorun.infを削除します。"
                FSO.DeleteFile sFileName, True
            End If
            ' WScript.Echo "autorun.infフォルダを作ります"
            Set f = FSO.CreateFolder(sFileName)
            f.Attributes = f.Attributes+3
        End If
    End If
End Sub

 

このスクリプトでは,Dドライブ以降のリムーバブルディスクを見つけると対策を施すかどうかメッセージを表示します。Yesを選択すると,autorun.infファイルがあればそれを削除してからautorun.infフォルダを作成します。

トラックバック


URL から "-MoIyadayo" を削除してトラックバックを送信してください。
トラックバックは承認後に表示されます。